*colorRotation
画像の色味を変更するフィルタ
**概要
輝度を維持して色相をシフトします。
同様の処理はphotoshopの色相・彩度フィルタでも可能ですが、この変換は(R-Y)/(B-Y)色空間で行われます。
色トレス抽出の判定空間と同じなので色トレスの微調整に使用できます。

**使い方
ctl(0)に元の色相角 / ctl(1)に変換先の色相角 を設定してください。
差分だけ色相を回転します。

destination	,ctl(0)	,変換元の色相角を255分法で
target	,ctl(1)	,変換先の色相角を255分法で

特定の色トレース部分を他の色に変換する時に使用できます。
画面の色の色情報は、スクリプトgetColorInfo.jsxで取得してください。

**ソース
---(
r:
put((76*r+150*g+29*b)/255,0),
put(b-get(0),1),
put(r-get(0),2),
put(c2d(get(1),get(2))+512,3),
put(c2m(get(1),get(2)),4),
put(r2x(get(3)+(ctl(0)-ctl(1))*4,get(4)),5),
put(r2y(get(3)+(ctl(0)-ctl(1))*4,get(4)),6),
put(get(0)+get(5),7),
put(get(0)+get(6),8),
put((255*get(0)-29*get(7)-76*get(8))/150,9),
get(8)

g:
get(9)

b:
get(7)

a
---)
**技術情報

内部的には色相角は1024分法です。

色相 0から1023までの値を指定するのですが、コントロールが255までの値なので
指定は4倍して適用されます。

